;*ELF-MON* 	*
;*
;*
;* original file dated July 22 2011 cosmacelf Yahoo group
;*By Walid Maalouli*

;HRJ A18 wants register names defined...

A	EQU	10
B	EQU	11
C	EQU	12
D	EQU	13
E	EQU	14
F	EQU	15

	org 0
 	GHI 0 		;CLEAR HIGH BYTE OF RE AND RF
 	PHI E 	
 	PHI F 	
 	LDI TEMP 	;READ MONITOR COMMAND CODE	
 	PLO F 	
 	SEX F 	
 	INP 4 	
 	PLO E 		;SAVE COMMAND IN RE
 	BNZ ONE 	;RUN COMMAND
 	SEQ 		;Q ON FOR INPUT
LOOP1:	BN4 LOOP1 	;WAIT FOR I TO BE PRESSED
 	INP 4 		;START ADDRESS OF PROGRAM
 	REQ 		;Q OFF
LOOP6:	B4 LOOP6 	;WAIT FOR I TO BE RELEASED
 	PLO 0 		;UPDATE PC (R0) AND RUN PROGRAM
ONE: 	GLO E 		;EDIT COMMAND
 	SDI 1 	
 	BNZ TWO 
 	SEQ 		;Q ON FOR INPUT
LOOP2:	BN4 LOOP2 	;WAIT FOR I TO BE PRESSED
 	INP 4 		;ADDRESS TO EDIT
 	LDN F		;SAVE IN RE <<---???
 	PLO F 	
NEXT1:	OUT 4 		;DISPLAY CONTENTS OF ADDRESS
 	DEC F 		;ADJUST RF AFTER OUT INSTRUCTION
LOOP3:	B4 LOOP3 	;WAIT FOR I TO BE RELEASED
LOOP4:	BN4 LOOP4 	;WAIT FOR I TO BE PRESSED
 	INP 4 		;TOGGLE IN NEW DATA BYTE
 	OUT 4 		;DISPLAY NEW DATA. RF NOW HAS NEXT ADDRESS
LOOP5:	B4 LOOP5 	;WAIT FOR I TO BE RELEASED
 	BR NEXT1 	;NEXT ADDRESS TO EDIT
TWO: 	GLO E 		;LIST COMMAND
 	SDI 2 
 	BNZ THREE 	
 	SEQ 		;Q ON FOR INPUT
LOOP7:	BN4 LOOP7	;WAIT FOR I TO BE PRESSED <<---???
 	INP 4 		;START ADDRESS OF LISTING
 	OUT 4 		;DISPLAY ADDRESS
 	DEC F 		;ADJUST RF AFTER OUT INSTRUCTION
LOOP8:	B4 LOOP8 	;WAIT FOR I TO BE RELEASED
 	REQ 		;Q OFF
	LDN F		;<<---???
 	PLO F 	
NEXT2:	OUT 4 		;DISPLAY ADDRESS CONTENTS
LOOP11: BN4 LOOP11 	;WAIT FOR I TO BE PRESSED
LOOP12: B4 LOOP12 	;WAIT FOR I TO BE RELEASED
 	BR NEXT2 	
THREE:	LDI INST 	;VIEW REGISTERS COMMAND (R1-RD)
 	PLO F 	
 	LDI 81H 	;STORE GLO INSTRUCTION FOR R1 IN RE
 	PLO E 	
 	GLO 1 	
 	SKP 	
INST:	NOP 	
 	STR F 	
 	OUT 4 		;DISPLAY REGISTER CONTENTS
 	DEC F 		;ADJUST RF AFTER OUT INSTRUCTION
LOOP13: BN4 LOOP13 	;WAIT FOR I TO BE PRESSED
LOOP14: B4 LOOP14 	;WAIT FOR I TO BE RELEASED
 	GLO E 	
 	SDI 90H 	;CHECK IF HIGH BYTE OF REGISTER DSPLAYED
 	BNF NEXT3 
 	GLO E 
 	ADI 0FH		;PUT GHI INSTRUCTION IN RE
 	PLO E 	
 	STR F 	
 	BR INST 
NEXT3:	GLO E 	
 	SMI 0FH		;PUT BACK GLO INSTRUCTION IN RE
 	PLO E 
 	INC E 		;NEXT REGISTER
 	GLO E 
 	SDI 8EH		;CHECK IF REGISTERS R1 TO RD PROCESSED
 	BZ MONEND 		;<<---???
 	GLO E 	
 	STR F 		;UPDATE GLO INSTRUCTION FOR NEXT REGISTER
 	BR INST 	
 	
MONEND: 	IDL 		;END OF MONITOR PROGRAM
TEMP: NOP 
	END